---

Hallo zusammen

Ich habe einen Ordner, in dem sich cirka 600 .csv-Dateien befinden. Bei allen Dateien muss ein Makro ausgeführt und nachher als .xls-File wieder abgespeichert werden.

Wie kann man einen automatischen Lauf über all diese Dateien starten, sodass die .csv's geöffnet werden, das Makro darin ausgeführt und die Datei (unter Beibehaltung des aktuellen Namen) als .xls-File abgespeichert wird?

Ich danke im Voraus für die Hilfe!

Beste Grüsse
Darksidy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Fertig hat dafür wahrscheinlich kaum einer was

Als Ansatz:

Nimm mal ein Makro auf in dem Du eine csv Datei aufmachst und als xls abspeicherst, dann hast Du mal ein erstes Gerüst eines Codes. Dann such Dir mal in Google einen Codeteil zum Bearbeiten von Directories. Bau dieses um Deinen bisherigen Code drumdrum, ersetze dabei dann die Dateinamen als Variable. Zum Schluss rufst Du dann noch die Subroutine von Deinem Macro auf.

Axel

------------------
CAD.DE: Inoffizielle deutsche CATIA Hilfeseite  Netiquette von cad.de
Berufliches Umfeld: comsol.net; comsol.ch; Euromanagers

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

versuche es mal so:

Code:

---

Sub MehrereOeffnen()
  Dim strVerzeichnis As String
  Dim strDatei As String
  Dim strTyp As String
  Dim strDateiname As String
  strTyp = "*.csv"
  Application.ScreenUpdating = False
  strVerzeichnis = "D:\Test\"
  strDateiname = Dir(strVerzeichnis & strTyp)
  Do While strDateiname <> ""
      Workbooks.Open Filename:=strVerzeichnis & strDateiname
      DeinMakro
      ActiveWorkbook.SaveCopyAs Application.Substitute(strDateiname, ".csv", "") & ".xls"
      ActiveWorkbook.Close
      strDateiname = Dir
  Loop
  Application.ScreenUpdating = True
End Sub

---

------------------
Bis später,
Karin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Bist Du aber lieb   

Axel

------------------
CAD.DE: Inoffizielle deutsche CATIA Hilfeseite  Netiquette von cad.de
Berufliches Umfeld: comsol.net; comsol.ch; Euromanagers

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

derartige Kleinigkeiten habe ich - meist in etwas abgewandelter Form, die man leicht anpassen kann - in meinem VBA-Archiv vorliegen und bin immer gerne bereit, sie mit anderen Usern zu teilen.   

------------------
Bis später,
Karin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo zusammen

Danke für Eure Beiträge, und Karin: Herzlichen Dank für diese pfannenfertige Deluxe-Version - funktioniert einwandfrei!

Beste Grüsse
Darksidy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo zusammen! VIelen Dank Karin für den Code - auch bei mir funktioniert er perfekt!

Allerdings habe ich das Problem, dass nach dem Konvertieren in die xls File komplett "zusammengestaucht" wird und die einzlnen Werte nicht mehr in den gewünschten Zellen sind. Gibt es dafür auch einen Code, der dies berücksichtigt?

Vielen lieben Dank für eure Hilfe!

Liebe Grüße,
Simon

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

dass nach dem Konvertieren in die xls File komplett "zusammengestaucht" wird und die einzlnen Werte nicht mehr in den gewünschten Zellen sind

---

und auf dem normalen weg csv öffnen passiert das nicht?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Nein, passiert nicht! Das ist auch etwas schwer zu verstehen und deshalb auch in der Frage nicht ganz einfach zu formulieren. Ich arbeite mit einer Simulationssoftware (Flexsim), die mir die Ergebnisse im csv Format ausgibt. Leider sind csv Dateien als Anhang hier im Forum nicht erlaubt.

Ich kenne es normalerweise immer nur so, dass die csv Datei (comma separated - wie der Name eben schon sagt) auf eine Spalte zusammengestaucht ist.
Ich habe mittlerweile noch was einen anderen Code entdeckt, der zwar das Konvertieren wieder schafft aber nicht das Umformatieren.

Ich glaub ich hab einfach nur einen Knoten im Kopf - das kann doch nicht so schwierig sein?!

Code:

---

Sub convertCSVtoXLS4()

Application.DisplayAlerts = False
myFile = ActiveWorkbook.Name
myPath = "C:\Ordner1\"
WorkFile = Dir(myPath & "*.CSV")

Do While WorkFile <> ""
  Application.StatusBar = "Now working on " & WorkFile
  Workbooks.Open Filename:=myPath & WorkFile
 
    Columns("A:A").Select
    Selection.TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, _
        Semicolon:=False, Comma:=True, Space:=False, Other:=False, FieldInfo _
        :=Array(Array(1, 1), Array(2, 1), Array(3, 1), Array(4, 1), Array(5, 1), Array(6, 1), _
        Array(7, 1), Array(8, 1), Array(9, 1), Array(10, 1), Array(11, 1), Array(12, 1), Array(13, 1 _
        '), Array(14, 1), Array(15, 1), Array(16, 1), Array(17, 1), Array(18, 1)), _
    TrailingMinusNumbers:=True
    Range("A1").Select

    ActiveWorkbook.SaveAs Filename:=myPath & _
      Left(ActiveWorkbook.Name, Len(ActiveWorkbook.Name) - 4), FileFormat:=xlNormal
  ActiveWorkbook.Close
  Windows(myFile).Activate
  WorkFile = Dir()
Loop

Application.StatusBar = False

End Sub

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo!

Ich kann das Problem jetzt noch einwenig präzisieren: mein Ausgangspunkt sind immer meine *.csv Dateien, die mir mein Simulationsprogramm geben. Die Zahlenkolonnen sind genau so angeorndet, wie ich das möchte und ich kann und will auch einfache Berechnung (diese kann ich mir über den Makrorekroder holen) erstellen. Wenn das Makro nun läuft und die Datei öffnet

Code:

---

 
Workbooks.Open Filename:=myPath & WorkFile

---

Werden die Spalten zusammengestaucht und diese falsche Anordnung (.csv typisch!) bleibt dann bestehen und gibt mir folglich die fehlerhafte .xls Datei aus.

Gibt es irgendeinen Weg dieses Durcheinander, das das Makro durch das öffnen der Datei verursacht, zu beheben bzw. gar nicht aufkommen zu lassen?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zum Öffnen in Excel hilft es oft die Extension csv in txt umzubennen und sie dann in Excel aufzumachen. Dann kannst Du erst mal schauen was ohne Makro in Excel ankommt.
Das hilft manchmal schon weiter.

Axel

------------------
CAD.DE: Inoffizielle deutsche CATIA Hilfeseite  Netiquette von cad.de
Berufliches Umfeld: comsol.net; comsol.ch; Euromanagers;  3D Printingservice

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Morgen,

versuche mal:

Workbooks.Open Filename:=myPath & WorkFile, Local:=True

CU, Bernd

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

ich finde die Lösung super aber habe das Problem, dass er die Dateien bei mir weiterhin als csv Datei abspeichert. Was mache ich falsch?

Eine weitere Ergänzug: Wie kann ich die Dateien an einem anderen Ort speichern.
Dateien liegen in:
C:\Users\Documents\Unterlagen
und sollen in
C:\Users\Documents\Unterlagen\done
gespeichert werden.

Danke euch

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

...welchen Code hast du genommen?

ungetestet.

Code:

---

Sub MehrereOeffnen()
  Dim strVerzeichnis As String
  Dim strZielVerz As String
  Dim strDatei As String
  Dim strTyp As String
  Dim strDateiname As String
  strTyp = "*.csv"
  Application.ScreenUpdating = False
  strVerzeichnis = "C:\Users\Documents\Unterlagen\"
  strZielVerz = "C:\Users\Documents\Unterlagen\done\"
  strDateiname = Dir(strVerzeichnis & strTyp)

  Do While strDateiname <> ""
      Workbooks.Open Filename:=strVerzeichnis & strDateiname, Local:=True
      'DeinMakro
      'ActiveWorkbook.SaveCopyAs Application.Substitute(strZielVerz & strDateiname, ".csv", "") & ".xls"

      ' XL 2010
      ActiveWorkbook.SaveAs Application.Substitute(strZielVerz & strDateiname, ".csv", "") & ".xls", FileFormat:=xlExcel8, _
      Password:="", WriteResPassword:="", ReadOnlyRecommended:=False, _
      CreateBackup:=False

      ActiveWorkbook.Close
      strDateiname = Dir
  Loop
  Application.ScreenUpdating = True
End Sub

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Simon,

ja, das ist ein häufiges Problem mit dem CSV-Format. Das sollte im Deutschen lieber SSV heissen - Semikolon separatet values. Darauf läuft's nämlich hinaus. Je nach Einstellung Deines Betriebssystems und Deines XL (ggf auch das des Herkunftsrechners, falls solche involviert sind), klappt das mal und mal nicht.
Ein komplett deutsches System wird CSV nur richtig in XL einlesen können, wenn die Werte mit Semikolon getrennt sind. Stehen da tatsächlich Kommata, ist das Ergebnis Glückssache.
Workaround: Umbenennen in TXT (ggf. per Makro), in XL öffnen und mit dem Textkonvertierungsassistenten (Daten - Text in Spalten...) richtig aufteilen. Zum Glück klappt das hervorragend mit dem Makrorekorder.

Grüsse,
Frank

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

ok es klappt jetzt. Vielen Dank. Mein Problem ist aber, dass Excel nach ca. 400 Dateien aufgibt mit dem Fehler, dass es zuviele Daten sind um es zu processen. Any Ideas? Danke euch!!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

je nachdem, wie Du die Dateien öffnest...
Machst Du das mit FOR...EACH, könntest Du die bearbeiteten Dateien in einen anderen Ordner verschieben, in der Schleife einen Zähler mitlaufen lassen und nach, sagen wir 200 Dateien die Schleife verlassen. Das ganze so oft, bis im Ursprungsordner keine Dateien mehr sind.
Man könnte aber auch als erstes die Dateien zählen und dann mit FOR...NEXT-Schleifen (Höchstwert wieder z.B. 200) alle Dateien abarbeiten.
Oder es gibt eine Systematik in den Dateinamen, die man abprüfen und einzeln abarbeiten könnte: Zuerst alle, die mit A anfangen etc.

Grüsse,
Frank

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke für die Hinweise, jetzt funktioniert alles.

Ein Problem besteht weiterhin. Ich formatiere die Zahlen mit dem Makro bereits, allerdings wird mir hinterher immer der Fehler angezeigt "number stored as text". Und daher wird die Formel nicht ausgeführt. Könnt ihr mir vielleicht weiterhelfen?

Herzlichen Dank

Das ist mein Code:
.....
Range("F9:J9").Select
    Range(Selection, Cells(Rows.Count, Selection.Column).End(xlUp)).Select
    Selection.NumberFormat = _
        "_ [$€-413] * #,##0.00_ ;_ [$€-413] * -#,##0.00_ ;_ [$€-413] * ""-""??_ ;_ @_ "
    Dim NextRow As Long
    NextRow = Range("E" & Rows.Count).End(xlUp).Row + 1
    Range("F" & NextRow & ":J" & NextRow).Formula = "=SUM(F9:F" & NextRow - 1 & ")"
    Range(Selection, Cells(Rows.Count, Selection.Column).End(xlUp)).Select
    Selection.Borders(xlDiagonalDown).LineStyle = xlNone
....
....
ActiveWorkbook.SaveAs Application.Substitute(strZielVerz & ActiveSheet.Range("B5").Text, ".csv", "") & ".xlsx", FileFormat:=xlOpenXMLWorkbook
      ActiveWorkbook.Close
      strDateiname = Dir
  Loop
  Application.ScreenUpdating = True
End Sub

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Das einfache Umformatieren bringt leider nix, wenn der Zellinhalt mal als Text erkannt wurde.
Das kann man auch direkt in Excel in einer Zelle ausprobieren. Nach dem Umformatieren der Zelle aus ein Zahlenformat muss man nochmal mit F2 eine Neu-Eingabe starten und mit <Enter> abschließen. Erst dann wird aus der Eingabe eine Zahl.
In Deinem Makro könntest Du in einer Schleife jeweils den Zellinhalt mit 1 multiplizieren. Damit wird dann automatisch wieder eine Zahl daraus (wenn es kein Text ist) und das neue Format wird übernommen.
Mathias

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

ok danke für den Hinweis. Könntest du mir sagen, wie ich den Bereich:
Range("F9:J9").Select
    Range(Selection, Cells(Rows.Count, Selection.Column).End(xlUp)).Select
mit 1 multiplizieren kann?

Danke

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

In etwa so:

For each cell in selection
  cell.value=cell.value*1
next

Mathias

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

perfekt - DANKE

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP