---

Hallo,
ich habe zwei dynamische Felder a() und b(), die während des Programmlaufs mit Daten gefüllt (Redim Preserv) werden.

Wie kann ich einem bestehenden Diagramm (chart) vom Typ xlXYScatterSmooth die Felder a() für die x-Daten und b() für die y-Daten zuweisen ?
Mit SeriesCollection erreiche ich immer nur das Zuweisen aus einem Tabellenbereich (Range).
(Excel 2000)

Grüße und Dank

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Wyndorps,

kleines Beispiel:

Code:

---

Option Explicit

Private Sub prcCreateChart(vntXValues As Variant, vntValues As Variant)
    Dim objChartObject As ChartObject
    Set objChartObject = Worksheets(1).ChartObjects.Add(200, 100, 400, 250)
    With objChartObject
        .Name = "Testdiagramm"
        With .Chart
            .ChartType = xlXYScatterSmooth
            .SeriesCollection.NewSeries
            .SeriesCollection(1).XValues = vntXValues
            .SeriesCollection(1).Values = vntValues
            .Legend.Delete
        End With
    End With
End Sub

Public Sub test()
    Dim x(9), y(9)
    Dim intIndex As Integer
    For intIndex = 0 To 9
        x(intIndex) = intIndex ^ 2
        y(intIndex) = intIndex * 2
    Next
    Call prcCreateChart(x, y)
End Sub

---

------------------
Gruß
Nepumuk

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Herzlichen Dank!
Funktioniert perfekt. 10U4U
Wyndorps

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP