---

Komponente-konfigurieren.png

Hallo,
ich bin auf der Suche nach einem Beispiel zum auslesen und setzen der Konfigurationen einer selektierten Komponente in einer Oberbaugruppe, und zwar ohne die einzelnen Konfigurationen der Oberbaugruppe zu aktivieren.

Mit Rechtsklick auf eine Komponente und Komponente konfigurieren bekomme ich ein Fenster wie im Bild zu sehen.
Hier könnte ich jetzt beliebig modifizieren.
Diese Informationen möchte ich zunächst in ein Array schreiben.

Code:

---

Dim ConfigCountOBgr    As Long                            'Anzahl der Konfigurationen
Dim ConfigNamesOBgr    As Variant                          'Namen der Konfigurationen
Dim i                  As Integer                          'Zähler
ConfigNamesOBgr = swModel.GetConfigurationNames            'Namen der Konfigurationen
ConfigCountOBgr = UBound(ConfigNamesOBgr)                  'Anzahl der Konfigurationen
   
ReDim Preserve referencedKonfig(ConfigCountOBgr)            'Array erweitern

For i = 0 To ConfigCountOBgr
       
            referencedKonfig(i).Config = Config                'Konfiguration der Oberbaugruppe
            referencedKonfig(i).RefConfig = selModelConfig      'Konfiguration der selektierten Komponente

            If Not CBool(CInt(swComp.IsSuppressed)) Then        'Wenn Komponente nicht unterdrückt ist
                referencedKonfig(i).IsSuppressed = False
            Else
                referencedKonfig(i).IsSuppressed = True
            End If
       
    Next i

---

Auf die Konfiguration der Oberbaugruppe greife ich wie üblich zu.

Code:

---

    Set swApp = Application.SldWorks                                           
    Set swModel = swApp.ActiveDoc                                              'aktive Baugruppe
    Set Configuration = swModel.GetActiveConfiguration
    Config = Configuration.Name

---

Auf die Konfiguration der selektierten Komponente greife ich so zu.

Code:

---

Dim swComp As SldWorks.Component2
Dim selModelConfig As String
Set swComp = SelMgr.GetSelectedObjectsComponent(i)
selModelConfig = swComp.ReferencedConfiguration                            'Konfigurationsname der selektierten Komponente

---

Nun müsste ich jede Konfiguration in der Oberbaugruppe aufrufen und dort jeweils die gesuchten Informationen abfragen.
Dies möchte ich aber vermeiden und ohne Konfigwechsel auslesen.
Der Makrorecorder nimmt hier leider nichts passendes auf.

Hat mir jemand den passenden Befehl zu dieser Abfrage?

Im nächsten Schritt wird die Komponente durch eine Unterbaugruppe ersetzt und nun möchte ich dieses Array wieder auslesen und die Konfigurationen wie gehabt einstellen, natürlich auch ohne Konfigwechsel der Oberbaugruppe.

Die Konfiguration der Unterbaugruppe wähle ich momentan mit diesem Befehl aus.

Code:

---

boolstatus = selModelASM.ReplaceComponents2(uBgrModelPathName, uBgrModelConfig, False, 1, True)

---

Bei diesem Befehl fehlt auch die Option, die Konfiguration der Oberbaugruppe zu definieren.

Hoffentlich gibt es dazu passende Befehle.
Wer kann weiterhelfen?

Grüße, Andi 

------------------
Hast du kein Problem?
Such dir eins. ( Und löse es )

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Andi

Ich hab dir einmal das Auslesen zusammen gebastelt.
(Vorlage: Get configurations of child components relative to configuration of parent)

Code:

---

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim mDoc As ModelDoc2

Dim swComp As SldWorks.Component2
Dim rootComp As Component2
Dim comp2 As Component2

Dim SelMgr As SelectionMgr
Dim configNames() As String
Dim config As Configuration
Dim childCompsObj() As Object

Dim i As Integer
Dim j As Integer

Public Sub Main()

Set swApp = Application.SldWorks
Set mDoc = swApp.ActiveDoc
Set SelMgr = mDoc.SelectionManager
Set swComp = SelMgr.GetSelectedObjectsComponent(1)

configNames = mDoc.GetConfigurationNames

For i = 0 To UBound(configNames)
Set config = mDoc.GetConfigurationByName(configNames(i))
Set rootComp = config.GetRootComponent3(True)
Debug.Print ("------------Processing config: " + config.Name + "------------")

childCompsObj = rootComp.GetChildren()

For j = 0 To UBound(childCompsObj)
Set comp2 = childCompsObj(j)
If comp2.Name = swComp.Name Then
Debug.Print ("Referenced config for " + comp2.Name2 + " is: " + comp2.ReferencedConfiguration)
Exit For
End If
Next

Next

End Sub

---

Das Ändern der Konfiguration der eingefügten Baugruppen sollte ähnlich sein. (ReferencedConfiguration Property (IComponent2))

Gruss Andreas

------------------
21 ist nur die halbe Antwort.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Andreas, 
wunderbar, das Auslesen klappt jetzt wie gewünscht.
Konnte dein Beispiel in mein Makro integrieren.
Die Reihenfolge der Konfigurationen ist zwar Historienbasiert, aber in diesem Fall benötige ich sie nicht alphabetisch sortiert.
Allerdings hätte ich für das Sortieren bereits eine Routine, für alle Fälle.

Jetzt mache ich mich an die nächsten Schritte ran.

Besten Dank schon mal dafür.
Evtl. melde ich mich nochmal, falls ich irgendwo hängen bleibe.

Grüße, Andi

------------------
Hast du kein Problem?
Such dir eins. ( Und löse es )

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP