Hot News:

Mit Unterstützung durch:

  Foren auf CAD.de (alle Foren)
  CATIA V5 Programmierung
  Zugewiesenes Material in Stückliste

Antwort erstellen  Neues Thema erstellen
CAD.de Login | Logout | Profil | Profil bearbeiten | Registrieren | Voreinstellungen | Hilfe | Suchen

Anzeige:

Darstellung des Themas zum Ausdrucken. Bitte dann die Druckfunktion des Browsers verwenden. | Suche nach Beiträgen nächster neuer Beitrag | nächster älterer Beitrag
Autor Thema:  Zugewiesenes Material in Stückliste (660 mal gelesen)
ryLIX
Mitglied
Maschinenbaumechaniker

Sehen Sie sich das Profil von ryLIX an!   Senden Sie eine Private Message an ryLIX  Schreiben Sie einen Gästebucheintrag für ryLIX

Beiträge: 8
Registriert: 27.08.2006

Windows10
Inventor 2014
CatiaV5R19

erstellt am: 11. Jun. 2018 19:23    Editieren oder löschen Sie diesen Beitrag!  <-- editieren / zitieren -->   Antwort mit Zitat in Fett Antwort mit kursivem Zitat    Unities abgeben: 1 Unity (wenig hilfreich, aber dennoch)2 Unities3 Unities4 Unities5 Unities6 Unities7 Unities8 Unities9 Unities10 Unities

Hi,
ich hab länger nach einer Möglichkeit gesucht habe wie ich Material, welches ich einem Part zugewiesen habe, ohne Nacharbeit in eine Eigenschaft bekomme damit es in der Stückliste angezeigt werden kann. Was man so im Forum findet ist zum Teil unvollständig oder umständlich.

Also habe mir dann selbst was gebaut.
Das Makro findet alle Parts in einem Produkt. Es werden nur Parts die die neue Benutzereigenschaft noch nicht haben und ein Material zugewiesen bekommen haben bearbeitet.

Mit der Variablen "myParamName" wird der Name der Eigenschaft bestimmt.
Die Materialbezeichnung wird nur aus dem Materialparameter des Parts gelesen.

Code:
Public iCounter As Integer
Public myParamName As String

Sub CatMain()
    Dim myProductDocument As ProductDocument
    Dim myProduct As Product
    'Catia Dokument holen
    If CATIA.Documents.Count <> 0 Then
        If TypeName(CATIA.ActiveDocument) = "ProductDocument" Then
            Set myProductDocument = CATIA.ActiveDocument
        Else
            MsgBox "Kein Produkt geladen!", vbCritical, "Warnung"
            Exit Sub
        End If
    Else
        MsgBox "Kein Dokument geöffnet!", vbCritical, "Warnung"
        Exit Sub
    End If
    'Root Produkt aus dem Dokument holen
    If myProductDocument.Product.Products.Count <> 0 Then
        Set myProduct = myProductDocument.Product
    Else
        MsgBox "Produkt in dem aktuellen Catia Dokument ist leer!", vbCritical, "Warnung"
        Exit Sub
    End If
    iCounter = 0 'Zähler Variable nullen
    myParamName = "Material" 'Name für die Benutzereigenschaft festlegen
    ScanStructure myProduct 'Prüffunktion zum finden der Parts
    MsgBox "Es wurden " & iCounter & " Parts bearbeitet", vbInformation, "Hinweis"

End Sub

Sub ScanStructure(ProductToScan As Product)
    Dim currentprod As Product 'Variable zum durchzählen der Produkte
    Dim refProd As Product 'Referenz Produkt für die Bearbeitung
    Dim refPart As Part 'Referenz Part für das Abfragen des Materials
    Dim myManager As MaterialManager 'Catia Material Manager Instanz
    Dim refMaterial As material 'Referenz Material für den Material Manager
    Dim refParamList As Parameters
   
    On Error Resume Next
   
    For Each currentprod In ProductToScan.Products 'Jedes Produkt das im Produkt aus dem Aufruf enthalten ist wird geprüft
        If currentprod.Products.Count > 0 Then 'Rekursion wenn im Produkt weitere Produkte sind
            ScanStructure currentprod 'Übergeben wird nun das grade zu prüfende Produkt
        Else
            Set refProd = currentprod.ReferenceProduct 'Ab hier sind keine weiteren Produkte mehr enthalten
            If TypeName(refProd.Parent) = "PartDocument" Then 'Erkennen ob in dem Produkt ein Part enthalten ist
                Set refPart = refProd.Parent.Part 'Part aus dem Produkt in die Referenz Variable übergeben
                Set myManager = refProd.GetItem("CATMatManagerVBExt") 'Material Manager aktivieren
                myManager.GetMaterialOnPart refPart, refMaterial 'Material aus dem Part abrufen
                If CheckNames(refProd.UserRefProperties) = 0 Then 'Nur wenn keine gleiche Eigenschaft vorhanden
                    If Not refMaterial Is Nothing Then 'Nur wenn ein Material vorhanden
                        Set myPropertyMaterial = refProd.UserRefProperties.CreateString(myParamName, refMaterial.Name) 'Neue Benutzereigenschaft anlegen und füllen
                        iCounter = iCounter + 1 'Zähler Variable eins weiter zählen
                    End If
                End If
            End If
        End If
    Next
   
End Sub

Public Function CheckNames(UsrParameters As Parameters) As Single
    Dim refParam As Parameter 'Referenz Parameter zur Abfrage der Eigenschaften
   
    For Each refParam In UsrParameters
        If InStr(1, refParam.Name, myParamName, vbTextCompare) <> 0 Then 'Vergleichen ob eine Eigenschaft mit der Bezeichnung vorhanden ist
            CheckNames = 1 'Eigenschaft gefunden Funktion wird vorzeitig beendet
            Exit Function
        End If
    Next
    CheckNames = 0 'Keine Eigenschaft gefunden

End Function


Vielleicht hat ja noch jemand Verwendung für dieses Makro.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

Anzeige.:

Anzeige: (Infos zum Werbeplatz >>)

Darstellung des Themas zum Ausdrucken. Bitte dann die Druckfunktion des Browsers verwenden. | Suche nach Beiträgen

nächster neuerer Beitrag | nächster älterer Beitrag
Antwort erstellen


Diesen Beitrag mit Lesezeichen versehen ... | Nach anderen Beiträgen suchen | CAD.de-Newsletter

Administrative Optionen: Beitrag schliessen | Archivieren/Bewegen | Beitrag melden!

Fragen und Anregungen: Kritik-Forum | Neues aus der Community: Community-Forum

(c)2023 CAD.de | Impressum | Datenschutz